Co to jest asembler?

Kody instrukcji umieszczane są w kolejnych komórkach pamięci, skąd mikroprocesor pobiera je, rozpoznaje operacje do wykonania i wykonuje te operacje. Kody binarne są słabo (czytaj wcale) czytelne dla ludzi. Jednakże to ludzie tworzą programy dla procesorów. Zatem zamiast stosowania niewygodnych i nieczytelnych kodów binarnych, stosują oni tzw. nazwy symboliczne. Przy odpowiedniej wprawie nazwy symboliczne są łatwe do zapamiętywania i analizowania. Każda instrukcja procesora posiada taką nazwę.

Na przykład:

LD   A,1       ; załaduj do rejestru akumulatora A liczbę 1
CALL PRINT_A   ; wywołaj procedurę pod adresem symbolicznym PRINT_A
ADD  HL,BC     ; do pary rejestrów HL dodaj zawartość pary rejestrów BC

itd.

Mnemoniki są dużo bardziej czytelne od kodów binarnych. Asembler tłumaczy mnemoniki na ich odpowiedniki binarne – to jest jego główna funkcja. Kod wynikowy z asemblera może być już bezpośrednio wykonany przez mikroprocesor. Zaletą programowania w asemblerze jest niesamowita szybkość programów. Wadą – cóż, trzeba dużo wiedzieć o samym komputerze i jego budowie.

Instrukcja dla użytkownika ZX ASSEMBLER II

(C) ARTIC COMPUTING LTD

ZAWARTOŚĆ

WPROWADZENIE
OGÓLNY OPIS
ZACZYNAMY
ZAPIS PROGRAMÓW
EDYTOR
SKŁADNIA POLECEŃ ASEMBLERA
    ETYKIETY
    TEKST
    LICZBY
    SEPARATORY
    NIESTANDARDOWE MNEMONIKI
    KOMENTARZE
ASEMBLACJA
    BŁĄD ETYKIETY
    BŁĄD SKOKU WZGLĘDNEGO
    BŁĄD PRZESUNIĘCIA
    BŁĄD LICZBY
    BRAK PAMIĘCI
    BŁĄD STOSU
    BŁĄD SKŁADNIOWY
MONITOR
    ROZKAZY
UŻYTECZNE PROCEDURY W ASEMBLERZE
WSKAZÓWKI DLA POCZĄTKUJĄCYCH
REGUŁY
POLECANA LITERATURA
ZESTAW ROZKAZÓW MIKROPROCESORA Z80

WPROWADZENIE

Celem programu ZX ASEMBLER jest ułatwienie całego procesu programowania w kodzie maszynowym na komputerach ZX81. Udostępnia on wszechstronne i łatwe w użyciu funkcje, przy jednoczesnym zachowaniu zdumiewająco dużego obszaru pamięci RAM dostępnej dla użytkownika. Program zajmuje 7K i mieści się w górnej połowie obszaru ROM (chodzi oczywiście o VB81), zatem w żaden sposób nie wpływa na system BASIC, który pracuje tak, jakby asemblera w ogóle nie było.

OGÓLNY OPIS

W programie występują dwie główne sekcje:

1. EDYTOR/ASEMBLER. Przy pomocy polecenia EDIT możesz wprowadzać i edytować swój kod asemblerowy, a następnie skompilować go poleceniem ASSEMBLE. EDYTOR został zaprojektowany specjalnie do wprowadzania kodu asemblerowego: używa on przewijania ekranu w górę i w dół, wyszukiwania tekstów, pozwala na wstawianie i usuwanie znaków oraz wierszy, posiada funkcję automatycznego powtarzania wszystkich klawiszy oraz system tworzenia odstępów przy etykietach i sterowania kursorem w czterech kierunkach. W wierszu może być do 31 znaków. ASEMBLER jest bardzo wszechstronny i udostępnia pełną listę mnemoników wraz z etykietami, pozwala na wprowadzanie liczb szesnastkowych i dziesiętnych oraz tekstu i komentarzy.
2. MONITOR. Udostępnia funkcje testowania i uruchamiania twojego programu w kodzie maszynowym. Udostępnia on również kilka użytecznych podprogramów (takich jak odczyt danych z klawiatury, wyświetlanie na ekranie... itp.).

Celem tej instrukcji jest wyjaśnienie sposobów pracy z EDYTOREM/ASEMBLEREM oraz z MONITOREM jak również przekazanie wskazówek i procedur dla początkujących oraz listy zbioru instrukcji mikroprocesora Z80.

ZX ASEMBLER jest potężnym oprogramowaniem i używany poprawnie może zwiększyć niesamowicie prędkość działania twoich programów.

ZACZYNAMY

ZX ASEMBLER jest automatycznie ładowany w momencie startu emulatora VB81. Zostaje on umieszczony w górnej połowie obszaru pamięci ROM, który rozpoczyna się od adresu 2000 szesnastkowo lub 8192 dziesiętnie. Ten obszar pamięci ZX81 jest zwykle chroniony przed zapisem podczas symulacji, chociaż możesz zezwolić na takie zapisy, lecz wtedy kod programu nie będzie bezpieczny i może zostać uszkodzony. Ustaw tę opcję tylko wtedy, gdy nie planujesz korzystania ze swojego asemblera.

Aby uruchomić ten program, musisz wpisać: RAND USR 8192 – program krótko się przedstawi. Jest to TRYB ROZKAZÓW dla ASEMBLERA. Wszystkie rozkazy są uruchamiane z tego miejsca przez POJEDYNCZE NACIŚNIĘCIE KLAWISZA. Aby powrócić do systemu BASIC, wpisz dwukrotnie Q (QUIT = REZYGNACJA).

W wersji II ZX ASEMBLERA dodano funkcję zwracania adresu startowego kodu. Jeśli wywołasz asembler w sposób następujący:

to zmienna S będzie zawierała adres twojego kodu po asemblacji. Jeśli nie wykonasz asemblacji kodu, to w S będzie umieszczony adres startowy ZX ASEMBLERA.

ZAPIS PROGRAMÓW

Aby zapisać skończony lub niekompletny program, naciśnij dwukrotnie Q w celu powrotu do systemu BASIC. Odkryjesz wtedy program BASIC składający się z dwóch wierszy, plus to, co wcześniej wprowadziłeś.

Wiersz nr 1 zawiera kod maszynowy. Wiersz nr 2 zawiera program źródłowy w asemblerze (bądź ostrożny przy przenumerowywaniu wierszy w VB81 – numery tych dwóch pierwszych wierszy powinny pozostać niezmienione). Na tym etapie możesz życzyć sobie usunąć wg potrzeby dowolny z tych wierszy i zapisać program w zwykły sposób (zostanie on umieszczony w katalogu taśmy ustawionym w VB81). Gdy ASEMBLER jest obecny w ROM, możesz w dowolnej chwili załadować ten program z powrotem i go dokończyć lub kontynuować pracę nad nim. Jeśli nie skończyłeś jeszcze swojego programu, możesz usunąć kod wynikowy (wiersz nr 1) i zapisać jedynie kod źródłowy programu. Najlepszym rozwiązaniem jest tworzenie kopii bezpieczeństwa kodu źródłowego dla przyszłych poprawek.

EDYTOR

Gdy wywołasz EDYTOR naciskając klawisz E, zostanie wyświetlony ekran z tekstem dotąd wprowadzonym. Będziesz znajdował się albo w miejscu, gdzie byłeś ostatnio przy wyjściu z EDYTORA, albo w miejscu wystąpienia błędu przy asemblacji (zobacz na ASEMBLACJĘ). Oprócz prostego wprowadzania tekstu EDYTOR udostępnia użytkownikowi kilka funkcji. Wszystkie te funkcje otrzymujemy z naciśniętym klawiszem SHIFT.

Funkcje:

Naciśnij:

Wszystkie klawisze posiadają funkcję autopowtarzania po upływie 1 sekundy.
EDYTOR pozwala wprowadzić w wierszu maksymalnie 31 znaków. Jeśli skończy się pamięć, to powrócisz do TRYBU ROZKAZÓW, gdzie pojawi się wiadomość OUT OF MEMORY (BRAK PAMIĘCI): wiersz, który właśnie wpisywałeś, zostanie usunięty, abyś mógł powrócić do EDYTORA i zdobyć nieco miejsca. Jeśli ma być zmieniona etykieta, to SHIFT A nie przesunie kursora w lewo, zamiast tego użyj SHIFT 5.

SKŁADNIA ASEMBLERA

Po przedstawieniu się programu otrzymasz do wyboru kilka rozkazów dla monitora, lecz najpierw zbadajmy Edytor/Asembler.

Aby wejść do Edytora, wpisz E. Ekran zostanie wyczyszczony i będzie wyświetlał graficzną spację ustawioną w 7-mej kolumnie od lewej krawędzi ekranu. Teraz jesteś gotowy do wprowadzania swojego programu w asemblerze.

ETYKIETY

Asembler akceptuje etykiety zbudowane z liter i cyfr, rozpoczynające się od litery, a po nich może bezpośrednio występować:

Aby wprowadzić etykietę, wpisz SHIFT A, a kursor przesunie się do lewej krawędzi ekranu. Otrzymujemy w ten sposób efekt wcięć w wierszach asemblera, które ułatwiają ich odczytywanie.

Przykład: procedura obliczania punktów w grze

SCORE1 = 5000
       JR BEGIN       ;skocz na początek.
SCORE  DB 00,00       ;dwa bajty na punktację.
BEGIN  LD HL,(SCORE)  ;pobierz punkty.
       INC HL         ;zwiększ je
       LD (SCORE),HL  ;zapisz nowe punkty
       LD (SCORE1),HL ;zapisz kopię pod 5000 HEX
       RET

Do etykiety można odwołać się z przesunięciem od -9 do +9. Np:

       LD A,(PTR+4)
       ...
PTR    DB 1,2,3,4,5,6

Rejestr A będzie zawierał 5. Jeśli nie zostanie podane przesunięcie, to  wynosi ono 0.

  A = 1

Uwaga: Odradzamy stosowania nazw takich samych jak nazwy rejestrów, np. BC, lub poprawne liczby szesnastkowe, np. ABCD, bo albo otrzymasz wiadomość o błędzie przy skokach względnych, albo konsekwencje będą potencjalnie katastrofalne.

TEKST

Jeśli chcesz wstawić jakiś tekst do swojego programu w asemblerze, to  użyj dyrektywy DEFM/DM. Sam tekst musi być umieszczony w cudzysłowach (SHIFT P lub klawisz " w VB81).

Przykład: wydruk wiadomości

       CALL PRINT
       DM "TUTAJ WPROWADZAMY TEKST"
       DB FF  ;zaznaczamy koniec tekstu

Przykład: tekst w asemblerze

       LD A,0        ;ustaw wartość początkową
CHECK  INC A         ;dodaj do niej 1
       CP "*"        ;sprawdź, czy jest *
       JR NZ CHECK   ;jeśli nie, wróć do CHECK
       CALL PRINTA   ;wydrukuj znak
       CALL PRINT    ;wydrukuj tekst
       DM " JEST ZNAKIEM *"
       DB FF

Eliminuje to potrzebę znajomości kodów znaków.

LICZBY

Asembler standardowo używa liczb szesnastkowych (o podstawie 16)

 8 bitowych od 0 do FF
16 bitowych od 000 do FFFF (musi być 3 lub 4 cyfry)

Liczby dziesiętne muszą być poprzedzone znakiem '+' lub '-'. Są one zawsze liczbami 16 bitowymi.

np. +1 jest reprezentowane jako 0001.

Asembler jest dosyć inteligentny w traktowaniu liczb tak, jak tego wymaga sytuacja – czasem jako 8 bitowe, a czasem jako 16 bitowe.

Przykład: ładowanie etykiety

TEST = +64
...
LD HL,TEST  ; 16 bit oczekiwane
LD A,TEST   ;  8 bit oczekiwane

Etykieta TEST jest traktowana w zaznaczonych miejscach odpowiednio jak liczba 16 bitowa lub 8 bitowa. Jednakże jeżeli Asembler oczekuje liczby 8 bitowej, a liczba ma wartość większą od FF lub +255, to w czasie asemblacji powstanie błąd NUMBER ERROR.

Przykład: liczby

LD HL,1    ;OK
LD A,+13   ;OK
LD A,101   ;Błąd

Jeśli chcesz umieścić w rejestrze liczbę, której nazwa jest taka sama jak nazwa rejestru, musisz poprzedzić ją cyfrą 0.

Przykład

LD A,B    ;umieszcza rejestr B w A
LD A,0B   ;umieszcza liczbę B w A

Jeśli chcesz umieścić parę liczb wewnątrz swojego kodu, użyj dyrektywy DEFB/DB dla liczb 8 bitowych i dyrektywy DEFW/DW dla liczb 16 bitowych. Każda z tych dyrektyw przyjmuje liczby rozdzielone przecinkami.

Przykłady: liczby w pamięci

TAB1  DB +15,+24,-43,0       ;liczby 8 bitowe
TAB2  DW FA99,+16333,+25872  ;liczby 16 bitowe

Aby zarezerwować miejsce w pamięci na jakikolwiek cel, powiedzmy 100 bajtów, użyj dyrektywy DEFS/DS.

Przykład:

BUF    DS 100 ;masz do swojej dyspozycji 100 bajtów

SEPARATORY

Każda instrukcja może być rozdzielana za pomocą spacji lub końca wiersza.

Spacji może być więcej niż jedna za wyjątkiem poniższych instrukcji, które należy wprowadzać dokładnie tak, jak przedstawiono poniżej:

LDA_A,I       _ oznacza jedną spację
LDA_I,A
LDA_R,A
LDA_A,R
EX_AF         ≡ EX AF,AF'
EX_DE,HL
EX_(SP),HL

NIESTANDARDOWE MNEMONIKI

Następujące mnemoniki są niestandardowe dla Z80

EX AF    ≡  EX AF,AF'
IM0 zamiast IM 0
IM1 zamiast IM 1
IM2 zamiast IM 2 

Instrukcje JP i JR nie mają przecinków, np. JR NZ +7

KOMENTARZE

ASEMBLACJA

Aby skompilować swój program, wpisz A i pojawi się napis ASSEMBLE. Teraz naciśnij NEWLINE i twój program zostanie przetłumaczony na kod maszynowy. Program wynikowy jest umieszczany pod adresem 4084 szesnastkowo lub 16516 dziesiętnie. To będzie wiersz z REM o numerze 1, gdy powrócisz do systemu BASIC. Jeśli uruchomiłeś ASEMBLER poleceniem

LET S=USR 8192

to zmienna S zawiera adres startowy twojego kodu po powrocie z Asemblera do systemu BASIC. Aby go uruchomić, wpisz

RAND USR S

Na początku swojego programu możesz użyć dyrektywy ORG n, aby utworzyć kod uruchamiany pod adresem n. Kod wciąż zostanie umieszczony przez asembler w wierszu nr 1, lecz możesz go przenieść w miejsce docelowe przy pomocy rozkazu COPY dostępnego w Asemblerze.

Jeśli zrobisz błąd, to zostanie wyświetlony odpowiedni komunikat. Wpisanie E wyświetli tekst programu na wierszu, w którym wystąpił błąd.

Możesz otrzymać poniższe komunikaty błędów:

BŁĄD ETYKIETY

1. Niezdefiniowana etykieta.
2. Nieprawidłowa definicja etykiety, np. rozpoczynająca się cyfrą. Jeśli źle wpiszesz mnemonik, to prawdopodobnie otrzymasz ten błąd, ponieważ asembler sądzi, że chcesz uzyskać dostęp do etykiety.

BŁĄD SKOKU WZGLĘDNEGO

BŁĄD PRZESUNIĘCIA

1. Ładowanie rejestru etykietą z przesunięciem.
   np. LD HL,(FRED +10)
    dozwolone tylko ± 9
2. Użycie rejestrów indeksowych ze zbyt dużym przesunięciem.
       IX,IY > +127 lub < -128

BŁĄD LICZBY

np. LD A,1000

BRAK PAMIĘCI

1. W Edytorze gdy program asemblerowy jest zbyt duży.
2. Podczas asemblacji, gdy nie ma dosyć miejsca na kompilację programu.

BŁĄD STOSU

BŁĄD SKŁADNI

np. ADD A,*

MONITOR

ROZKAZY

UŻYTECZNE PROCEDURY W ASEMBLERZE

      LD D,+10     ; wiersz 10 – liczony od 0!
      LD E,+14     ; kolumna 14 – również od 0!
      CALL PRDE    ; drukuj tekst na 10,14
      DM "HELLO"   ; tekst do wydruku
      DB FF        ; znacznik końca tekstu
      ...          ; kontynuacja programu

INKEY PUSH BC ; zachowaj rejestry na stosie
      PUSH DE
      PUSH HL
      LD BC,(4025) ; załaduj kody skanowania
      LD D,C       ; sprawdź, czy jest wciśnięty klawisz
      INC D
      LD A,1       ; załóż, że nie
      JR Z INK1    ; jeśli nie, to pomiń wywołanie ROM
      CALL 07BD    ; zdekoduj kod klawisza
      LD A,(HL)    ; pobierz kod
INK1  POP HL       ; odtwórz rejestry
      POP DE
      POP BC
      RET          ; powróć z kodem w A
	
FILL  PUSH BC      ; zachowaj używane rejestry
      PUSH HL
      LD HL,(400C) ; ustaw HL na DFILE
      INC HL       ; pomiń startowy znak NEWLINE
      LD C,18      ; 24 wiersze do wypełnienia
FILL1 LD B,20      ; w każdym po 32 znaki z A
FILL2 LD (HL),A    ; wypełnij jeden wiersz
      INC HL
      DJNZ FILL2
      LD (HL),+118 ; umieść NEWLINE na kocu wiersza
      INC HL       ; przejdź do następnego wiersza
      DEC C        ; jeśli nie koniec, kontynuuj
      JR NZ FILL1  ; z resztą ekranu
      POP HL       ; odtwórz rejestry
      POP BC
      RET          ; i powróć
	
PRDE  CALL ATDE    ; oblicz pozycję DE w HL
      POP DE       ; ustaw DE na początek tekstu
PRDE1 LD A,(DE)    ; pobierz znak
      INC DE       ; następna pozycja w tekście
      CP FF        ; sprawdź znacznik końca tekstu
      JR NZ PRDE2  ; jeśli nie koniec, kontynuuj
      EX DE,HL     ; inaczej skocz tuż za znacznik
      JP (HL)      ; końca tekstu
PRDE2 LD (HL),A    ; umieść znak w DFILE
      INC HL       ; przesuń się na następną pozycję
      JR PRDE1     ; kontynuuj drukowanie
	
ATDE  PUSH BC      ; zachowaj używane rejestry
      PUSH DE
      LD H,0
      LD L,D       ; HL = D
      LD B,H
      LD C,L       ; BC =   D
      ADD HL,HL    ; HL =  2D
      ADD HL,HL    ; HL =  4D
      ADD HL,HL    ; HL =  8D
      ADD HL,HL    ; HL = 16D
      ADD HL,HL    ; HL = 32D
      ADD HL,BC    ; HL = 33D
      LD D,0       ; DE = E
      ADD HL,DE    ; HL = 33D + E
      EX DE,HL     ; DE = 33D + E
      LD HL,(400C) ; HL = DFILE
      INC HL       ; HL = DFILE+1
      ADD HL,DE    ; HL = DFILE+1+33D+E
      POP DE       ; odtwórz rejestry
      POP BC
      RET          ; powróć z adresem w HL

WSKAZÓWKI DLA POCZĄTKUJĄCYCH

NIE WPADAJ W PANIKĘ!!!

REGUŁY

1. Zachowuj swoje otoczenie. W podprogramach umieszczaj używane rejestry na stosie rozkazami PUSH. Przed powrotem odtwarzaj je ze stosu w kolejności odwrotnej do ich zapisu.

   e.g.   LD A,27    ; wpisz wartość do A
          PUSH HL    ; zapisz HL na stosie
          PUSH BC    ; zapisz BC na stosie
          CALL PRINT ; pisz znak z A
          POP BC     ; odtwórz BC ze stosu
          POP HL     ; odtwórz HL ze stosu

2. Wszystko to, co zostało umieszczone na stosie w danym podprogramie, musi być w tym samym podprogramie zdjęte ze stosu przed wykonaniem RET.
   Załóżmy, iż FRED jest podprogramem drukującym znak.

   FRED   LD A,17    ; wpisz wartość do A
          PUSH AF    ; zapisz AF na stosie
          CALL FRED  ; drukuj znak
          RET        ; powrót?

   Ta procedura spowoduje zablokowanie komputera, ponieważ przed wykonaniem RET należy wykonać POP AF.

3. Pamiętaj, w którym miejscu pamięci znajduje się twój stos. Nie umieszczaj swoich procedur zbyt blisko stosu, ponieważ rosnąc może on  zniszczyć część ich kodu.
4. Skoki względne posiadają ograniczenie zasięgu w stosunku do bieżącej pozycji:

           + 127 bajtów w przód – 128 bajtów wstecz

5. Czytaj jak najwięcej informacji na temat programowania.
6. Umieszczaj w podprogramach tyle, ile się rozsądnie da umieścić.

POLECANA LITERATURA

W języku angielskim:
Machine Language programming made simple for your Sinclair.
Understanding your ZX81 ROM, Melbourne House
Programming the Z80, Rodney Zaks, Sybex
Z80 Instruction Handbook, Intel