CreatePipe PROTO pReadHandle:     DWORD,\
                 pWriteHandle:    DWORD,\
                 pPipeAttributes: DWORD,\
                 nBufferSize:     DWORD

• pReadHandle jest wskazaniem zmiennej typu DWORD, która otrzyma uchwyt do końca odczytującego potoku
• pWriteHandle jest wskazaniem zmiennej typu DWORD, która otrzyma uchwyt do końca zapisującego potoku
• pPipeAttributes wskazuje strukturę SECURITY_ATTRIBUTES, która określa, czy zwrócone uchwyty zapisu i odczytu mogą być dziedziczone przez procesy potomne
• nBufferSize jest sugerowanym rozmiarem bufora rezerwowanego do użytku przez dany potok. Jest to jedynie rozmiar sugerowany. Możesz zastosować NULL, aby nakazać funkcji użycie standardowego rozmiaru.

1. Utwórz anonimowy potok za pomocą CreatePipe. Nie zapomnij ustawić pola bInheritable struktury SECURITY_ATTRIBUTES na TRUE, aby uchwyty mogły być dziedziczone.
2. Teraz musisz przygotować parametry przekazywane do CreateProcess, ponieważ wykorzystamy to wywołanie do załadowania i uruchomienia aplikacji konsoli. Istotną strukturą jest STARTUPINFO. Struktura ta określa wygląd głównego okna procesu potomnego, gdy się ono pojawia po raz pierwszy. Jest bardzo ważna dla naszych celów. Możesz ukryć główne okno i przekazać uchwyt potoku potomnemu procesowi konsoli do pracy z nim. Poniżej wyszczególniam pola struktury, które muszą być wypełnione:

• cb → rozmiar struktury STARTUPINFO.
• dwFlags → bitowe znaczniki określające, które pola struktury zawierają ważne informacje, również steruje stanem pokazywania i ukrywania głównego okna. Dla naszych celów powinieneś zastosować znaczniki STARTF_USESHOWWINDOW oraz STARTF_USESTDHANDLES.
• hStdOutput i hStdError → uchwyty, które chcesz, aby proces potomny używał jako standardowe uchwyty wyjścia i błędu. Dla naszych celów przekażemy uchwyt zapisujący potoku jako standardowe wyjście i wyjście błędu procesu potomnego. Zatem gdy proces potomny wyśle coś na standardowe wyjście / wyjście błędu, to w rzeczywistości prześle dane poprzez potok do naszego procesu nadrzędnego.
• wShowWindow ® rządzi stanem ukrywania / pokazywania głównego okna. Dla naszych celów nie życzymy sobie pokazania okna konsoli, zatem umieszczamy w tym polu znacznik SW_HIDE.

3. Wywołaj CreateProcess, aby załadować aplikację potomną. Po sukcesie tego wywołania proces potomny jest wciąż uśpiony. Został załadowany do pamięci, lecz nie uruchomił się natychmiast.
4. Zamknij uchwyt zapisujący potoku. Jest to konieczne, ponieważ proces nadrzędny nie używa uchwytu zapisującego potoku, a potok nie będzie pracował, jeśli istnieją dwa końce zapisujące, zatem MUSIMY zamknąć go zanim rozpoczniemy odczyt z potoku. Jednakże nie zamykaj uchwytu zapisującego przed wywołaniem CreateProcess, gdyż zaburzy to twój potok. Powinieneś zamknąć go tuż po powrocie z wywołania CreateProcess, a przed odczytem danych z końca odczytującego potoku.
5. Teraz możesz odczytać dane z końca odczytującego potoku za pomocą ReadFile. Przy pomocy tej funkcji uruchamiasz proces potomny. Rozpocznie on wykonanie, a kiedy zapisze coś do standardowego uchwytu wyjścia (który w rzeczywistości jest uchwytem do końca zapisującego potoku), dane zostaną przesłane poprzez potok na koniec odczytujący. Możesz potraktować funkcję ReadFile jak wysysanie danych z końca odczytującego potoku. Funkcję tę należy wykonywać cyklicznie, aż zwróci 0, co oznacza, iż nie ma więcej danych do odczytania. Z danymi odczytanymi z potoku możesz zrobić co ci się podoba. W naszym przykładzie wstawiam je do kontrolki edycyjnej.
6. Zamknij uchwyt odczytujący potoku.

.386

.MODEL FLAT, STDCALL

OPTION CASEMAP:NONE

INCLUDE    \masm32\include\windows.inc
INCLUDE    \masm32\include\user32.inc
INCLUDE    \masm32\include\kernel32.inc
INCLUDE    \masm32\include\gdi32.inc
INCLUDELIB \masm32\lib\gdi32.lib
INCLUDELIB \masm32\lib\user32.lib
INCLUDELIB \masm32\lib\kernel32.lib

WinMain PROTO :DWORD, :DWORD, :DWORD, :DWORD

.CONST

IDR_MAINMENU EQU     101
IDM_ASSEMBLE EQU 40001

.DATA

ClassName          DB "PipeWinClass", 0
AppName            DB "Potok Jednokierunkowy", 0
EditClass          DB "EDIT", 0
CreatePipeError    DB "Błąd przy tworzeniu potoku", 0
CreateProcessError DB "Błąd przy tworzeniu procesu", 0

;--------------------------------------------------------------
;UWAGA:
;Poniższy wiersz umożliwia wywołanie programu ml.exe. Jeśli
;znajduje się on w innym katalogu niż podany poniżej, to
;musisz odpowiednio zmodyfikować polecenie. W przeciwnym
;razie prezentowany przykład nie uruchomi tego procesu
;--------------------------------------------------------------

CommandLine DB "\masm32\bin\ml /c /coff /Cp test.asm", 0

.DATA?

hInstance HINSTANCE ?
hwndEdit  DD        ?

.CODE

start:
   
    INVOKE GetModuleHandle, NULL
    mov    hInstance, eax
    INVOKE WinMain, hInstance, NULL, NULL, SW_SHOWDEFAULT
    INVOKE ExitProcess, eax

WinMain PROC hInst:     DWORD,\
             hPrevInst: DWORD,\
             CmdLine:   DWORD,\
             CmdShow:   DWORD

LOCAL wc   : WNDCLASSEX
LOCAL msg  : MSG
LOCAL hwnd : HWND

    mov    wc.cbSize, SIZEOF WNDCLASSEX
    mov    wc.style, CS_HREDRAW OR CS_VREDRAW
    mov    wc.lpfnWndProc, OFFSET WndProc
    mov    wc.cbClsExtra, NULL
    mov    wc.cbWndExtra, NULL
    push   hInst
    pop    wc.hInstance
    mov    wc.hbrBackground, COLOR_APPWORKSPACE
    mov    wc.lpszMenuName, IDR_MAINMENU
    mov    wc.lpszClassName, OFFSET ClassName
    INVOKE LoadIcon, NULL, IDI_APPLICATION
    mov    wc.hIcon, eax
    mov    wc.hIconSm, eax
    INVOKE LoadCursor, NULL, IDC_ARROW
    mov    wc.hCursor, eax
    INVOKE RegisterClassEx, ADDR wc
    INVOKE CreateWindowEx, WS_EX_CLIENTEDGE,\
                           ADDR ClassName, ADDR AppName,\
                           WS_OVERLAPPEDWINDOW OR WS_VISIBLE,\
                           CW_USEDEFAULT, CW_USEDEFAULT,\
                           467, 200, NULL, NULL, hInst, NULL
    mov    hwnd, eax

    .WHILE TRUE
        INVOKE GetMessage, ADDR msg, NULL, 0, 0
        .BREAK .IF (!eax)
        INVOKE TranslateMessage, ADDR msg
        INVOKE DispatchMessage, ADDR msg
    .ENDW

    mov eax, msg.wParam
    ret

WinMain ENDP

WndProc PROC hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM

LOCAL rect:         RECT
LOCAL hRead:        DWORD
LOCAL hWrite:       DWORD
LOCAL startupinfo:  STARTUPINFO
LOCAL pinfo:        PROCESS_INFORMATION
LOCAL buffer[1024]: BYTE
LOCAL bytesRead:    DWORD
LOCAL hdc:          DWORD
LOCAL sat:          SECURITY_ATTRIBUTES

    .IF uMsg==WM_CREATE
        INVOKE CreateWindowEx, NULL, ADDR EditClass, NULL,\
                               WS_CHILD OR WS_VISIBLE OR \
                               ES_MULTILINE OR ES_AUTOHSCROLL OR \
                               ES_AUTOVSCROLL, 0, 0, 0, 0,\
                               hWnd, NULL, hInstance, NULL
        mov    hwndEdit, eax
    .ELSEIF uMsg==WM_CTLCOLOREDIT
        INVOKE SetTextColor, wParam, Yellow
        INVOKE SetBkColor, wParam, Black
        INVOKE GetStockObject, BLACK_BRUSH
        ret
    .ELSEIF uMsg==WM_SIZE
        movzx   edx, WORD PTR lParam
        movzx   ecx, WORD PTR lParam + 2
        INVOKE MoveWindow, hwndEdit, 0, 0, edx, ecx, TRUE
    .ELSEIF uMsg==WM_COMMAND
        .IF lParam==0
            mov eax, wParam
            .IF ax==IDM_ASSEMBLE
                mov   sat.nLength, SIZEOF SECURITY_ATTRIBUTES
                mov   sat.lpSecurityDescriptor, NULL
                mov   sat.bInheritHandle, TRUE
                INVOKE CreatePipe, ADDR hRead, ADDR hWrite, ADDR sat, NULL
                .IF eax==NULL
                    INVOKE MessageBox, hWnd, ADDR CreatePipeError, ADDR AppName, MB_ICONERROR OR MB_OK
                .ELSE
                    mov       startupinfo.cb, SIZEOF STARTUPINFO
                    INVOKE GetStartupInfo, ADDR startupinfo
                    mov       eax, hWrite
                    mov       startupinfo.hStdOutput, eax
                    mov       startupinfo.hStdError, eax
                    mov       startupinfo.dwFlags, STARTF_USESHOWWINDOW OR STARTF_USESTDHANDLES
                    mov       startupinfo.wShowWindow, SW_HIDE

;-------------------------------------------------
; Tworzenie procesu
;-------------------------------------------------

                    INVOKE CreateProcess, NULL, ADDR CommandLine,\
                                          NULL, NULL, TRUE, NULL, NULL,\
                                          NULL, ADDR startupinfo,\
                                          ADDR pinfo
                    .IF eax==NULL
                        INVOKE MessageBox, hWnd,\
                                           ADDR CreateProcessError,\
                                           ADDR AppName,\
                                           MB_ICONERROR OR MB_OK
                    .ELSE
                        INVOKE CloseHandle, hWrite
                        .WHILE TRUE
                            INVOKE RtlZeroMemory, ADDR buffer, 1024
                            INVOKE ReadFile, hRead, ADDR buffer, 1023, ADDR bytesRead, NULL
                            .BREAK .IF (!eax)
                            INVOKE SendMessage, hwndEdit, EM_SETSEL, -1, 0
                            INVOKE SendMessage, hwndEdit, EM_REPLACESEL, FALSE, ADDR buffer
                       .ENDW
                    .ENDIF
                    INVOKE CloseHandle, hRead
                    INVOKE CloseHandle, pinfo.hProcess
                    INVOKE CloseHandle, pinfo.hThread
                .ENDIF
            .ENDIF
        .ENDIF
    .ELSEIF uMsg==WM_DESTROY
        INVOKE PostQuitMessage, NULL
    .ELSE
        INVOKE DefWindowProc, hWnd, uMsg, wParam, lParam		
        ret
    .ENDIF

    xor eax, eax
    ret

WndProc ENDP

END start

#define IDR_MAINMENU 101
#define IDM_ASSEMBLE 40001

IDR_MAINMENU MENU DISCARDABLE
{
  POPUP "&Dzia-anie"
  {
    MENUITEM "&Uruchom Asembler", IDM_ASSEMBLE
  }
}

    .ELSEIF uMsg==WM_CTLCOLOREDIT
        INVOKE SetTextColor, wParam, Yellow
        INVOKE SetBkColor, wParam, Black
        INVOKE GetStockObject, BLACK_BRUSH
        ret

    .IF ax==IDM_ASSEMBLE
        mov  sat.nLength, SIZEOF SECURITY_ATTRIBUTES
        mov  sat.lpSecurityDescriptor, NULL
        mov  sat.bInheritHandle, TRUE

    INVOKE CreatePipe, ADDR hRead, ADDR hWrite, ADDR sat, NULL

    mov    startupinfo.cb, SIZEOF STARTUPINFO
    INVOKE GetStartupInfo, ADDR startupinfo
    mov    eax, hWrite
    mov    startupinfo.hStdOutput, eax
    mov    startupinfo.hStdError, eax
    mov    startupinfo.dwFlags, STARTF_USESHOWWINDOW OR STARTF_USESTDHANDLES
    mov    startupinfo.wShowWindow, SW_HIDE

    INVOKE CreateProcess, NULL, ADDR CommandLine,\
                          NULL, NULL, TRUE, NULL, NULL,\
                          NULL, ADDR startupinfo,\
                          ADDR pinfo

INVOKE CloseHandle, hWrite

    .WHILE TRUE
        INVOKE RtlZeroMemory, ADDR buffer, 1024
        INVOKE ReadFile, hRead, ADDR buffer, 1023, ADDR bytesRead, NULL
        .BREAK .IF (!eax)
        INVOKE SendMessage, hwndEdit, EM_SETSEL, -1, 0
        INVOKE SendMessage, hwndEdit, EM_REPLACESEL, FALSE, ADDR buffer
    .ENDW

INVOKE CloseHandle, hRead

{********************************
**  I Liceum Ogólnokształcące  **
**           w Tarnowie        **
**       mgr Jerzy Wałaszek    **
********************************}

program Pipe;

uses Windows;

const
  IDR_MAINMENU       =   101;
  IDM_ASSEMBLE       = 40001;
  ClassName          = 'PipeWinClass';
  AppName            = 'Potok Jednokierunkowy';
  EditClass          = 'EDIT';
  CreatePipeError    = 'Błąd przy tworzeniu potoku';
  CreateProcessError = 'Błąd przy tworzeniu procesu';

//--------------------------------------------------------------
//UWAGA:
// Poniższy wiersz umożliwia wywołanie programu ml.exe. Jeśli
// znajduje się on w innym katalogu niż podany poniżej, to
// musisz odpowiednio zmodyfikować polecenie. W przeciwnym
// razie prezentowany przykład nie uruchomi tego procesu
//--------------------------------------------------------------

CommandLine = 'c:\masm32\bin\ml /c /coff /Cp test.asm';

var
  hInstance : HINST;
  hwndEdit  : HANDLE;

function WndProc(hWnd:HWND;uMsg:UINT;wParam:WPARAM;lParam:LPARAM) : longint;
var
  rect          : RECT;
  sat           : SECURITY_ATTRIBUTES;
  startupinfo   : STARTUPINFO;
  pinfo         : PROCESS_INFORMATION;
  buffer        : array[1..1023] of byte;
  hRead         : longword;
  hWrite        : longword;
  bytesRead     : longword;
  hdc           : longword;

begin
  Result := 0;
  case uMsg of
    WM_CREATE:
      hwndEdit := CreateWindowEx(0,EditClass,0,
                  WS_CHILD or WS_VISIBLE or ES_MULTILINE or ES_AUTOHSCROLL or
                  ES_AUTOVSCROLL,0,0,0,0,hWnd,0,hInstance,0);
    WM_CTLCOLOREDIT:
    begin     
      SetTextColor(wParam,$00ffff);
      SetBkColor(wParam,$000000);
      Result := GetStockObject(BLACK_BRUSH);
    end;
    WM_SIZE:
      MoveWindow(hwndEdit,0,0,lParam and $ffff,lParam shr 16,true);
    WM_COMMAND:
      if (lParam = 0) and ((wParam and $ffff) = IDM_ASSEMBLE) then
      begin
        sat.nLength := sizeof(SECURITY_ATTRIBUTES);
        sat.lpSecurityDescriptor := 0;
        sat.bInheritHandle             := true;
        if not CreatePipe(hRead,hWrite,@sat,0) then
          MessageBox(hWnd,CreatePipeError,AppName,MB_ICONERROR or MB_OK)
        else
        begin
          with startupinfo do
          begin
            cb := sizeof(STARTUPINFO);
            GetStartupInfo(@startupinfo);
            hStdOutput  := hWrite;
            hStdError   := hWrite;
            dwFlags     := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
            wShowWindow := SW_HIDE;
          end;
      
//-------------------------------------------------
// Tworzenie procesu
//-------------------------------------------------

          if not CreateProcess(0,CommandLine,0,0,true,0,0,0,startupinfo,pinfo) then
            MessageBox(hWnd,CreateProcessError,AppName,MB_ICONERROR or MB_OK)
          else
          begin
            CloseHandle(hWrite);
            while true do
            begin
              FillChar(buffer,1024,0);
              if not ReadFile(hRead,buffer,1023,bytesRead,0) then break;
              SendMessage(hwndEdit,EM_SETSEL,-1,0);
              SendMessage(hwndEdit,EM_REPLACESEL,0,longint(@buffer));
            end;
          end;
          CloseHandle(hRead);
          CloseHandle(pinfo.hProcess);
          CloseHandle(pinfo.hThread);
        end;
      end;
    WM_DESTROY: PostQuitMessage(0);
    else Result := DefWindowProc(hWnd,uMsg,wParam,lParam);
  end;
end;

function WinMain(hInst,hPrevInst,CmdLine,CmdShow:longword) : longint;
var
  wc   : WNDCLASSEX;
  msg  : MSG;
  hwnd : HWND;

begin
  with wc do
  begin
    cbSize        := sizeof(WNDCLASSEX);
    style         := CS_HREDRAW or CS_VREDRAW;
    lpfnWndProc   := @WndProc;
    cbClsExtra    := 0;
    cbWndExtra    := 0;
    hInstance     := hInst;
    hbrBackground := COLOR_APPWORKSPACE;
    lpszMenuName  := IDR_MAINMENU;
    lpszClassName := ClassName;
    hIcon         := LoadIcon(0,IDI_APPLICATION);
    hIconSm       := hIcon;
    hCursor       := LoadCursor(0,IDC_ARROW);
  end;
  RegisterClassEx(wc);
  hwnd := CreateWindowEx(WS_EX_CLIENTEDGE,ClassName,AppName,
          WS_OVERLAPPEDWINDOW or WS_VISIBLE,CW_USEDEFAULT,CW_USEDEFAULT,
          467,200,0,0,hInst,0);
  while GetMessage(msg,0,0,0) do
  begin
    TranslateMessage(msg);
    DispatchMessage(msg);
  end;
  Result := msg.wParam;
end;

begin
  hInstance := GetModuleHandle(0);
  ExitProcess(WinMain(hInstance,0,0,SW_SHOWDEFAULT));
end.