1. Wypełnij strukturę NOTIFYICONDATA o następujących polach:

NOTIFYICONDATA STRUCT
    cbSize           DWORD ?
    hwnd             DWORD ?
    uID              DWORD ?
    uFlags           DWORD ?
    uCallbackMessage DWORD ?
    hIcon            DWORD ?
    szTip            BYTE 64 DUP (?)
NOTIFYICONDATA ENDS

• cbSize → Rozmiar tej struktury.
• hwnd → Uchwyt okna, które otrzyma powiadomienie, gdy ponad ikoną zasobnika wystąpi jakieś zdarzenie myszki.
• uID → Stała używana w charakterze identyfikatora ikony. To ty decydujesz o jej wartości. W przypadku posiadania kilku ikon zasobnika będziesz mógł sprawdzić, z której z nich pochodzi dane powiadomienie.
• uFlags → Określa pola tej struktury, które zawierają istotne dane:
  • NIF_ICON - dane zawiera pole hIcon
  • NIF_MESSAGE - dane zawiera pole uCallbackMessage
  • NIF_TIP - dane zawiera pole szTip
• uCallbackMessage ® Prywatna wiadomość, którą system Windows wyśle do okna określonego w polu hwnd , gdy wystąpi zdarzenie myszki ponad ikoną zasobnika. Wiadomość tę tworzysz sam
• hIcon → Uchwyt ikony, którą chcesz wstawić do ikony zasobnika.
• szTip → 64 bajtowy ciąg, w którym zawarty zostanie łańcuch tekstowy z podpowiedzią używaną przy wskazaniu ikony zasobnika kursorem myszki.

2. Wywołaj funkcję Shell_NotifyIcon zdefiniowaną w pliku dołączalnym shell32.inc. Funkcja ta ma następujący prototyp:

Shell_NotifyIcon PROTO dwMessage:DWORD ,pnid:DWORD

• dwMessage jest rodzajem wiadomości do wysłania powłoce systemu:
  • NIM_ADD - dodaje ikonę do obszaru statusu.
  • NIM_DELETE - usuwa ikonę z obszaru statusu.
  • NIM_MODIFY - zmienia ikonę w obszarze statusu.
• pnid jest wskazaniem struktury NOTIFYICONDATA wypełnionej odpowiednimi wartościami.

1. Utwórz menu wyskakujące (popup menu) wywołując CreatePopupMenu. Funkcja ta tworzy puste menu. Jeśli się powiedzie, to w rejestrze eax zwraca uchwyt menu.
2. Przy pomocy funkcji AppendMenu, InsertMenu lub InsertMenuItem dodaj elementy menu.
3. Gdy chcesz wyświetlić wyskakujące menu na pozycji kursora myszki, wywołaj GetCursorPos w celu otrzymania współrzędnych ekranowych kursora, a następnie wywołaj TrackPopupMenu, aby wyświetlić je na tych współrzędnych. Gdy użytkownik wybierze jakiś element z menu, system Windows wyśle wiadomość WM_COMMAND do twojej procedury okna jak przy normalnym wyborze z menu.

1. Gdy jest wyświetlane wyskakujące menu i klikniesz gdziekolwiek poza nim, to menu nie znika natychmiast jak powinno. Dzieje się tak dlatego, gdyż okno otrzymujące powiadomienia z menu MUSI być oknem pierwszoplanowym. Aby to naprawić, po prostu wywołaj SetForegroundWindow.
2. Po wywołaniu SetForegroundWindow odkryjesz, iż przy pierwszym wyświetleniu menu wyskakującego wszystko działa poprawnie, lecz przy następnych razach menu pokazuje się na moment i natychmiast znika. Zachowanie to jest "celowe", co cytuję za MSDN (Microsoft Developer Network - baza wiedzy Microsoft dla twórców oprogramowania). W najbliższej przyszłości konieczne jest przełączenie zadania do programu będącego właścicielem ikony zasobnika. Możesz wymusić to przełączenie zadania wysyłając wiadomość do okna tego programu. Po prostu zastosuj PostMessage, a nie SendMessage!

.386

.MODEL FLAT, STDCALL

OPTION CASEMAP:NONE

INCLUDE    \masm32\include\windows.inc
INCLUDE    \masm32\include\user32.inc
INCLUDE    \masm32\include\kernel32.inc
INCLUDE    \masm32\include\shell32.inc
INCLUDELIB \masm32\lib\user32.lib
INCLUDELIB \masm32\lib\kernel32.lib
INCLUDELIB \masm32\lib\shell32.lib

WinMain PROTO :DWORD, :DWORD, :DWORD, :DWORD

.CONST

WM_SHELLNOTIFY EQU WM_USER + 5
IDI_TRAY       EQU    0
IDM_RESTORE    EQU 1000
IDM_EXIT       EQU 1010

.DATA

ClassName     DB "TrayIconWinClass", 0
AppName       DB "Ikona Zasobnika Systemowego", 0
RestoreString DB "&Przywróć", 0
ExitString    DB "&Zakończ program", 0

.DATA?

hInstance  D ?
note       NOTIFYICONDATA <>
hPopupMenu DD ?

.CODE

start:
    INVOKE GetModuleHandle, NULL
    mov    hInstance, eax
    INVOKE WinMain, hInstance, NULL, NULL, SW_SHOWDEFAULT
    INVOKE ExitProcess, eax

WinMain PROC hInst:     HINSTANCE,\
             hPrevInst: HINSTANCE,\
             CmdLine:   LPSTR,\
             CmdShow:   DWORD

LOCAL wc   : WNDCLASSEX
LOCAL msg  : MSG
LOCAL hwnd : HWND

    mov    wc.cbSize, SIZEOF WNDCLASSEX
    mov    wc.style, CS_HREDRAW OR CS_VREDRAW OR CS_DBLCLKS
    mov    wc.lpfnWndProc, OFFSET WndProc
    mov    wc.cbClsExtra, NULL
    mov    wc.cbWndExtra, NULL
    push   hInst
    pop    wc.hInstance
    mov    wc.hbrBackground, COLOR_APPWORKSPACE
    mov    wc.lpszMenuName, NULL
    mov    wc.lpszClassName, OFFSET ClassName
    INVOKE LoadIcon, NULL, IDI_APPLICATION
    mov    wc.hIcon, eax
    mov    wc.hIconSm, eax
    INVOKE LoadCursor, NULL, IDC_ARROW
    mov    wc.hCursor, eax
    INVOKE RegisterClassEx, ADDR wc
    INVOKE CreateWindowEx, WS_EX_CLIENTEDGE,\
                           ADDR ClassName, ADDR AppName,\
                           WS_OVERLAPPED + WS_CAPTION + \
                           WS_SYSMENU + WS_MINIMIZEBOX + \
                           WS_MAXIMIZEBOX + WS_VISIBLE,\
                           CW_USEDEFAULT, CW_USEDEFAULT, 350, 200,\
                           NULL, NULL, hInst, NULL
    mov    hwnd, eax

    .WHILE TRUE
        INVOKE GetMessage, ADDR msg, NULL, 0, 0
        .BREAK .IF (!eax)
        INVOKE TranslateMessage, ADDR msg
        INVOKE DispatchMessage, ADDR msg
    .ENDW

    mov eax, msg.wParam
    ret

WinMain ENDP

WndProc PROC hWnd:HWND,  uMsg:UINT,  wParam:WPARAM,  lParam:LPARAM

LOCAL pt:         POINT
LOCAL rect: RECT

    .IF uMsg==WM_CREATE
        INVOKE CreatePopupMenu
        mov    hPopupMenu, eax
        INVOKE AppendMenu, hPopupMenu, MF_STRING, IDM_RESTORE, ADDR RestoreString
        INVOKE AppendMenu, hPopupMenu, MF_STRING, IDM_EXIT, ADDR ExitString
    .ELSEIF uMsg==WM_DESTROY
        INVOKE DestroyMenu, hPopupMenu
        INVOKE PostQuitMessage, NULL
    .ELSEIF uMsg==WM_SIZE
        .IF wParam==SIZE_MINIMIZED
            mov    note.cbSize, SIZEOF NOTIFYICONDATA
            push   hWnd
            pop    note.hwnd
            mov    note.uID, IDI_TRAY
            mov    note.uFlags, NIF_ICON + NIF_MESSAGE + NIF_TIP
            mov    note.uCallbackMessage, WM_SHELLNOTIFY
            INVOKE LoadIcon, NULL, IDI_WINLOGO
            mov    note.hIcon, eax
            INVOKE lstrcpy, ADDR note.szTip, ADDR AppName
            INVOKE ShowWindow, hWnd, SW_HIDE
            INVOKE Shell_NotifyIcon, NIM_ADD, ADDR note
        .ENDIF
    .ELSEIF uMsg==WM_COMMAND
        .IF lParam==0
            INVOKE Shell_NotifyIcon, NIM_DELETE, ADDR note
            mov    eax, wParam
            .IF ax==IDM_RESTORE
                INVOKE ShowWindow, hWnd, SW_RESTORE
            .ELSE
                INVOKE DestroyWindow, hWnd
            .ENDIF
        .ENDIF
    .ELSEIF uMsg==WM_SHELLNOTIFY
        .IF wParam==IDI_TRAY
            .IF lParam==WM_RBUTTONDOWN
                INVOKE GetCursorPos, ADDR pt
                INVOKE SetForegroundWindow, hWnd
                INVOKE TrackPopupMenu, hPopupMenu,\
                                       TPM_RIGHTALIGN OR TPM_RIGHTBUTTON,\
                                       pt.x, pt.y, NULL, hWnd, NULL
                INVOKE PostMessage, hWnd, WM_NULL, 0, 0
            .ELSEIF lParam==WM_LBUTTONDBLCLK
                INVOKE SendMessage, hWnd, WM_COMMAND, IDM_RESTORE, 0
            .ENDIF
        .ENDIF
    .ELSE
        INVOKE DefWindowProc, hWnd, uMsg, wParam, lParam		
        ret
    .ENDIF

    xor eax, eax
    ret

WndProc ENDP

END start

    .IF uMsg==WM_CREATE
        INVOKE CreatePopupMenu
        mov    hPopupMenu, eax
        INVOKE AppendMenu, hPopupMenu, MF_STRING, IDM_RESTORE, ADDR RestoreString
        INVOKE AppendMenu, hPopupMenu, MF_STRING, IDM_EXIT, ADDR ExitString

AppendMenu PROTO hMenu:      DWORD,\
                 uFlags:     DWORD,\
                 uIDNewItem: DWORD,\
                 lpNewItem:  DWORD

• hMenu jest uchwytem menu, do którego chcesz dołączać element.
• uFlags informuje system Windows o typie dołączanego do menu elementy, czy jest to grafika rastrowa, łańcuch znakowy, element rysunkowy właściciela, czy jest on aktywny, czy wyłączony itp. Pełną listę znajdziesz jak zwykle w pliku pomocy biblioteki API Win32. W naszym przykładzie używamy znacznika MF_STRING, który oznacza, iż element menu jest łańcuchem znakowym.
• uIDNewItem jest numerem ID elementu menu. Jest to wartość zdefiniowana przez użytkownika, która reprezentuje dany element menu.
• lpNewItem określa zawartość elementu menu w zależności od zawartości parametru uFlags. Ponieważ umieściliśmy tam MF_STRING, parametr lpNewItem musi zawierać wskazanie łańcucha znakowego, który będzie wyświetlany w menu wyskakującym.

    .ELSEIF uMsg==WM_SIZE
        .IF wParam==SIZE_MINIMIZED
            mov    note.cbSize, SIZEOF NOTIFYICONDATA
            push   hWnd
            pop    note.hwnd
            mov    note.uID, IDI_TRAY
            mov    note.uFlags, NIF_ICON + NIF_MESSAGE + NIF_TIP
            mov    note.uCallbackMessage, WM_SHELLNOTIFY
            INVOKE LoadIcon, NULL, IDI_WINLOGO
            mov    note.hIcon, eax
            INVOKE lstrcpy, ADDR note.szTip, ADDR AppName
            INVOKE ShowWindow, hWnd, SW_HIDE
            INVOKE Shell_NotifyIcon, NIM_ADD, ADDR note
        .ENDIF

.ELSEIF uMsg==WM_SHELLNOTIFY
        .IF wParam==IDI_TRAY
            .IF lParam==WM_RBUTTONDOWN
                INVOKE GetCursorPos, ADDR pt
                INVOKE SetForegroundWindow, hWnd
                INVOKE TrackPopupMenu, hPopupMenu,\
                                       TPM_RIGHTALIGN OR TPM_RIGHTBUTTON,\
                                       pt.x, pt.y, NULL, hWnd, NULL
                INVOKE PostMessage, hWnd, WM_NULL, 0, 0
            .ELSEIF lParam==WM_LBUTTONDBLCLK
                INVOKE SetForegroundWindow, hWnd
                INVOKE SendMessage, hWnd, WM_COMMAND, IDM_RESTORE, 0
            .ENDIF
        .ENDIF

TrackPopupMenu PROTO hMenu:     DWORD,\
                     uFlags:    DWORD,\
                     x:         DWORD,\
                     y:         DWORD,\
                     nReserved: DWORD,\
                     hWnd:      DWORD,\
                     prcRect:   DWORD

• hMenu jest uchwytem wyskakującego menu, które ma zostać wyświetlone.
• uFlags określa opcje tej funkcji, np. jak rozmieścić menu względem później podanych współrzędnych oraz który przycisk myszki zostanie użyty do wyboru z menu. W naszym przykładzie stosujemy TPM_RIGHTALIGN, aby umieścić menu na lewo od współrzędnych.
• x i y określają położenie menu we współrzędnych ekranu.
• nReserved musi mieć wartość NULL.
• hWnd jest uchwytem okna, które będzie otrzymywało wiadomości z tego menu.
• prcRect jest prostokątem na ekranie, gdzie można kliknąć myszką bez usuwania menu. Zwykle wstawiamy tutaj wartość NULL, zatem gdy użytkownik kliknie gdziekolwiek poza wyskakujące menu, zostanie ono usunięte.

    INVOKE Shell_NotifyIcon, NIM_DELETE, ADDR note
    mov    eax, wParam
    .IF ax==IDM_RESTORE
        INVOKE ShowWindow, hWnd, SW_RESTORE
    .ELSE
        INVOKE DestroyWindow, hWnd
    .ENDIF

{********************************
**  I Liceum Ogólnokształcące  **
**           w Tarnowie        **
**       mgr Jerzy Wałaszek    **
********************************}

program TrayIcon;

uses Windows;

const
  WM_SHELLNOTIFY = WM_USER + 5;
  NIF_MESSAGE    =    1;
  NIF_ICON       =    2;
  NIF_TIP        =    4;
  NIM_ADD        =    0;
  NIM_DELETE     =    2;
  IDI_TRAY       =    0;
  IDM_RESTORE    = 1000;
  IDM_EXIT       = 1010;
  ClassName      = 'TrayIconWinClass';
  AppName        = 'Ikona Zasobnika Systemowego';
  RestoreString  = '&Przywróć';
  ExitString     = '&Zakończ program';

var
  hInstance  : HINST;
  note       : NOTIFYICONDATA;
  hPopupMenu : longword;

function WndProc(hWnd:HWND;uMsg:UINT;wParam:WPARAM;lParam:LPARAM) : longint;
var
  pt   : POINT;
  rect: RECT;

begin
  Result := 0;
  case uMsg of
    WM_CREATE:
    begin
      hPopupMenu := CreatePopupMenu;
      AppendMenu(hPopupMenu,MF_STRING,IDM_RESTORE,RestoreString);
      AppendMenu(hPopupMenu,MF_STRING,IDM_EXIT,ExitString);
    end;
    WM_DESTROY:
    begin
      DestroyMenu(hPopupMenu);
      PostQuitMessage(0);
    end;
    WM_SIZE:
      if wParam = SIZE_MINIMIZED then
      begin
        note.cbSize           := sizeof(NOTIFYICONDATA);
        note.wnd              := hWnd;
        note.uID              := IDI_TRAY;
        note.uFlags           := NIF_ICON + NIF_MESSAGE + NIF_TIP;
        note.uCallbackMessage := WM_SHELLNOTIFY;
        note.hIcon            := LoadIcon(0,IDI_WINLOGO);
        note.szTip            := AppName;
        ShowWindow(hWnd,SW_HIDE);
        Shell_NotifyIcon(NIM_ADD,@note);
      end;
    WM_COMMAND:
      if lParam = 0 then
      begin
        Shell_NotifyIcon(NIM_DELETE,@note);
        if (wParam and $ffff) = IDM_RESTORE then
          ShowWindow(hWnd,SW_RESTORE)
        else
          DestroyWindow(hWnd);
      end;
    WM_SHELLNOTIFY:
      if wParam = IDI_TRAY then
        case lParam of
          WM_RBUTTONDOWN:
          begin
            GetCursorPos(pt);
            SetForegroundWindow(hWnd);
            TrackPopupMenu(hPopupMenu,TPM_RIGHTALIGN or TPM_RIGHTBUTTON,pt.x,pt.y,0,hWnd,rect);
            PostMessage(hWnd,WM_NULL,0,0);
          end;
          WM_LBUTTONDBLCLK:
            SendMessage(hWnd,WM_COMMAND,IDM_RESTORE,0);
        end;
    else Result := DefWindowProc(hWnd,uMsg,wParam,lParam);
  end;
end;

function WinMain(hInst,hPrevInst:HINST;CmdLine:LPSTR;CmdShow:DWORD) : longint;
var
  wc   : WNDCLASSEX;
  msg : MSG;
  hwnd: HWND;

begin
  with wc do
  begin
    cbSize        := sizeof(WNDCLASSEX);
    style         := CS_HREDRAW or CS_VREDRAW or CS_DBLCLKS;
    lpfnWndProc   := @WndProc;
    cbClsExtra    := 0;
    cbWndExtra    := 0;
    hInstance     := hInst;
    hbrBackground := COLOR_APPWORKSPACE;
    lpszMenuName  := 0;
    lpszClassName := ClassName;
    hIcon         := LoadIcon(0,IDI_APPLICATION);
    hIconSm       := hIcon;
    hCursor       := LoadCursor(0,IDC_ARROW);
  end;
  RegisterClassEx(wc);
  hwnd := CreateWindowEx(WS_EX_CLIENTEDGE,ClassName,AppName,
          WS_OVERLAPPED + WS_CAPTION + WS_SYSMENU + WS_MINIMIZEBOX +
          WS_MAXIMIZEBOX + WS_VISIBLE,CW_USEDEFAULT,CW_USEDEFAULT,
          350,200,0,0,hInst,0);
  while GetMessage(msg,0,0,0) do
  begin
    TranslateMessage(msg);
    DispatchMessage(msg);
  end;
  Result := msg.wParam;
end;

begin
  hInstance := GetModuleHandle(0);
  ExitProcess(WinMain(hInstance,0,0,SW_SHOWDEFAULT));
end.