• wywołaj BeginPaint w odpowiedzi na wiadomość WM_PAINT.
• wywołaj GetDC w odpowiedzi na inne wiadomości
• wywołaj CreateDC, aby utworzyć swój własny kontekst urządzenia.

• Za pomocą wywołania BeginPaint pobierz uchwyt do kontekstu urządzenia.
• Pomaluj obszar roboczy.
• Za pomocą wywołania EndPaint zwolnij uchwyt kontekstu urządzenia.

.386
.MODEL FLAT, STDCALL

OPTION CASEMAP:NONE

WinMain PROTO :DWORD, :DWORD, :DWORD, :DWORD

INCLUDE    \masm32\include\windows.inc
INCLUDE    \masm32\include\user32.inc
INCLUDE    \masm32\include\kernel32.inc
INCLUDELIB \masm32\lib\user32.lib
INCLUDELIB \masm32\lib\kernel32.lib

.DATA

ClassName DB "SimpleWinClass",0
AppName   DB "Nasze okno z tekstem",0
OurText   DB "Asembler Win32 jest wspaniały i łatwy!",0

.DATA?

hInstance   HINSTANCE ?
CommandLine LPSTR     ?

.CODE

start:
    INVOKE GetModuleHandle, NULL
    mov    hInstance, eax
    INVOKE GetCommandLine
    mov    CommandLine, eax
    INVOKE WinMain, hInstance, NULL, CommandLine, SW_SHOWDEFAULT
    INVOKE ExitProcess, eax

WinMain PROC hInst:     HINSTANCE,\
             hPrevInst: HINSTANCE,\
             CmdLine:   LPSTR,\
             CmdShow:   DWORD

LOCAL wc:   WNDCLASSEX
LOCAL msg:  MSG
LOCAL hwnd: HWND

    mov    wc.cbSize, SIZEOF WNDCLASSEX
    mov    wc.style, CS_HREDRAW OR CS_VREDRAW
    mov    wc.lpfnWndProc, OFFSET WndProc
    mov    wc.cbClsExtra, NULL
    mov    wc.cbWndExtra, NULL
    push   hInst
    pop    wc.hInstance
    mov    wc.hbrBackground, COLOR_WINDOW+1
    mov    wc.lpszMenuName, NULL
    mov    wc.lpszClassName, OFFSET ClassName
    INVOKE LoadIcon, NULL, IDI_APPLICATION
    mov    wc.hIcon, eax
    mov    wc.hIconSm, 0
    INVOKE LoadCursor, NULL, IDC_ARROW
    mov    wc.hCursor, eax
    INVOKE RegisterClassEx, ADDR wc
    INVOKE CreateWindowEx, NULL, ADDR ClassName, ADDR AppName,\
                           WS_OVERLAPPEDWINDOW,\ 
                           CW_USEDEFAULT, CW_USEDEFAULT,\
                           CW_USEDEFAULT, CW_USEDEFAULT,\
                           NULL, NULL, hInst, NULL
    mov    hwnd, eax
    INVOKE ShowWindow, hwnd, SW_SHOWNORMAL
    INVOKE UpdateWindow, hwnd
    .WHILE TRUE
        INVOKE GetMessage, ADDR msg, NULL, 0, 0
        .BREAK .IF (!eax)
        INVOKE TranslateMessage, ADDR msg
        INVOKE DispatchMessage,  ADDR msg
    .ENDW

    mov    eax, msg.wParam
    ret

WinMain ENDP

WndProc PROC hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM

LOCAL hdc:  HDC
LOCAL ps:   PAINTSTRUCT
LOCAL rect: RECT

    .IF uMsg==WM_DESTROY
        INVOKE PostQuitMessage, NULL
    .ELSEIF uMsg==WM_PAINT
        INVOKE BeginPaint, hWnd, ADDR ps
        mov    hdc, eax
        INVOKE GetClientRect, hWnd, ADDR rect
        INVOKE DrawText, hdc, ADDR OurText, -1, ADDR rect,\
               DT_SINGLELINE OR DT_CENTER OR DT_VCENTER
        INVOKE EndPaint, hWnd, ADDR ps
    .ELSE
        INVOKE DefWindowProc, hWnd, uMsg, wParam, lParam
        ret
    .ENDIF

    xor eax, eax
    ret

WndProc ENDP

END start

LOCAL hdc:  HDC 
LOCAL ps:   PAINTSTRUCT 
LOCAL rect: RECT

• hdc używane jest do przechowywania uchwytu kontekstu urządzenia zwróconego przez wywołanie BeginPaint.
• ps jest strukturą PAINTSTRUCT. Zwykle nie korzystamy z wartości w ps. Przekazywana jest ona do BeginPaint i wypełniana przez system Windows odpowiednimi wartościami. Następnie przekazuje się ps do funkcji EndPaint, gdy skończymy malowanie na obszarze roboczym okna.
• rect jest strukturą RECT zdefiniowaną następująco:

RECT STRUCT
    left   LONG ?
    top    LONG ?
    right  LONG ?
    bottom LONG ?
RECT ENDS

    INVOKE BeginPaint, hWnd, ADDR ps 
    mov    hdc, eax 
    INVOKE GetClientRect, hWnd, ADDR rect 
    INVOKE DrawText, hdc, ADDR OurText, -1, ADDR rect, \ 
           DT_SINGLELINE OR DT_CENTER OR DT_VCENTER 
    INVOKE EndPaint, hWnd, ADDR ps

DrawText PROTO hdc:      HDC,\
               lpString: DWORD,\
               nCount:   DWORD,\
               lpRect:   DWORD,\
               uFormat:  DWORD

• hdc jest uchwytem kontekstu urządzenia
• lpString jest wskazaniem łańcucha tekstowego, który chcesz narysować w danym prostokącie. Łańcuch ten musi być zakończony znakiem o kodzie 0, w przeciwnym razie musisz określić jego długość w następnym parametrze, nCount
• nCount jest liczbą znaków do narysowania. jeśli łańcuch jest zakończony zerem, to nCount musi przyjąć wartość -1. W przeciwnym razie nCount musi podawać liczbę znaków do narysowania z łańcucha lpString.
• lpRect jest wskazaniem prostokąta (struktury typu RECT), w których chcesz narysować dany łańcuch tekstowy. Zwróć uwagę, iż prostokąt ten również kadruje wydruk, tj. nie mógłbyś narysować tego łańcucha poza granicami prostokąta.
• uFormat jest wartością określającą sposób wyświetlenia łańcucha tekstowego w prostokącie. Używamy trzech wartości połączonych operatorem OR.


• DT_SINGLELINE określa tekst jednowierszowy
• DT_CENTER wyśrodkowuje tekst w poziomie
• DT_VCENTER wyśrodkowuje tekst w pionie. Musi być stosowana razem z DT_SINGLELINE.

Po zakończeniu malowania na obszarze roboczym okienka musisz wywołać funkcję EndPaint, aby zwolnić uchwyt kontekstu urządzenia.

I to wszystko. Podsumujmy główne punkty tutaj:

• W odpowiedzi na wiadomość WM_PAINT wywołujesz parę BeginPaint-EndPaint.
• Pomiędzy tymi wywołaniami robisz co chcesz z obszarem roboczym okna.
• Jeśli chcesz przemalować swój obszar roboczy w odpowiedzi na inne wiadomości, to masz do wyboru dwa rozwiązania:
  
  • Użyj pary GetDC-ReleaseDC i pomiędzy tymi wywołaniami narysuj, co trzeba.
  • Wywołaj InvalidateRect lub UpdateWindow, aby unieważnić cały obszar roboczy, co zmusi system Windows do umieszczenia wiadomości WM_PAINT w kolejce wiadomości dla twojego okna i w efekcie spowoduje odświeżenie obszaru roboczego w sekcji WM_PAINT.
    

{********************************
**  I Liceum Ogólnokształcące  **
**           w Tarnowie        **
**       mgr Jerzy Wałaszek    **
********************************}

program TextPaint;

uses Windows;

function WndProc(h:HWND;uMsg:UINT;wP:WPARAM;lP:LPARAM) : longint;
const
  OurText = 'FreePascal jest wspaniały i łatwy';
var
  HDevCnt: HDC;
  ps     : PAINTSTRUCT;
  r      : RECT;
begin
  WndProc := 0;
  case uMsg of
    WM_DESTROY: PostQuitMessage(0);
    WM_PAINT   : begin
                   HDevCnt := BeginPaint(h,ps);
                   GetClientRect(h,r);
                   DrawText(HDevCnt,OurText,-1,r,DT_SINGLELINE or DT_CENTER or DT_VCENTER);
                   EndPaint(h,ps);
                 end;
    else  WndProc := DefWindowProc(h,uMsg,wP,lP);
  end;
end;

function WinMain(hI,hPI:HINST;CmdLine:LPSTR;cmdShow:longint) : longint;
const
  ClassName = 'SimpleWinClass';
var
  wc : WndClassEx;
  ms : msg;
  h  : HWnd;
begin
  wc.cbSize        := SizeOf(WndClassEx);
  wc.style         := CS_HREDRAW or CS_VREDRAW;
  wc.lpfnWndProc   := @WndProc;
  wc.cbClsExtra    := 0;
  wc.cbWndExtra    := 0;
  wc.hInstance     := hI;
  wc.hbrBackground := COLOR_WINDOW + 1;
  wc.lpszMenuName  := 0;
  wc.lpszClassName := ClassName;
  wc.hIcon         := LoadIcon(0,IDI_APPLICATION);
  wc.hIconSm       := wc.hIcon;
  wc.hCursor       := LoadCursor(0,IDC_ARROW);
  RegisterClassEx(wc);
  h := CreateWindowEx(0,ClassName,'Nasze okno z tekstem',
                      WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,CW_USEDEFAULT,
                      CW_USEDEFAULT,CW_USEDEFAULT,0,0,hI,0);
  ShowWindow(h,CmdShow);
  UpdateWindow(h);
  while GetMessage(ms,0,0,0) do
  begin
    TranslateMessage(ms);
    DispatchMessage(ms);
  end;
  WinMain := ms.wParam;
end;

begin 
  ExitProcess(WinMain(GetModuleHandle(0),0,0,SW_SHOWDEFAULT));
end.