1. Wątek interfejsu użytkownika: ten typ wątku tworzy swoje własne okno, zatem otrzymuje wiadomości z systemu Windows. Może współpracować z użytkownikiem poprzez swoje własne okna, stąd pochodzi jego nazwa. Wątek tego rodzaju jest podmiotem reguły Mutexu z Win16, która zezwala tylko na pojedynczy wątek interfejsu użytkownika w 16 bitowym jądrze graficznym. Gdy tego rodzaju wątek interfejsu użytkownika wykonuje kod w obrębie 16-bitowego jądra graficznego, inne wątki interfejsu użytkownika nie mogą korzystać z usług tego jądra. Sytuacja ta jest charakterystyczna dla Windows 95, ponieważ pod maską system ten zawiera 16-bitowe jądro. W systemie Windows NT/2000/XP nie istnieje Mutex z Win16, zatem wątki interfejsu użytkownika działają znacznie lepiej niż w Windows 95 (który to system i tak jest już historią).
2. Wątek roboczy: ten typ wątku nie tworzy okna, zatem nie może odbierać żadnych wiadomości z systemu Windows. Istnieje głównie po to, aby wykonywać przydzieloną mu pracę w tle innych procesów, stąd nazwa wątek roboczy.

CreateThread PROTO lpThreadAttributes: DWORD,\ 
                   dwStackSize:        DWORD,\ 
                   lpStartAddress:     DWORD,\ 
                   lpParameter:        DWORD,\ 
                   dwCreationFlags:    DWORD,\ 
                   lpThreadId:         DWORD 

• lpThreadAttributes ® możesz zastosować wartość NULL, jeśli chcesz, aby wątek posiadał standardowy deskryptor zabezpieczeń.
• dwStackSize → określa rozmiar stosu wątku. Jeśli chcesz, aby wątek posiadał taki sam rozmiar stosu jak wątek główny, zastosuj NULL jako ten parametr.
• lpStartAddress ® adres funkcji wątku. Jest to funkcja, która wykona pracę przeznaczoną dla wątku. Funkcja ta MUSI otrzymywać dokładnie jeden 32-bitowy parametr i zwracać wartość 32-bitową.
• lpParameter → parametr przekazywany do funkcji wątku.
• dwCreationFlags ® 0 oznacza, iż wątek zostanie uruchomiony natychmiast po jego utworzeniu. Jest to przeciwieństwo znacznika CREATE_SUSPENDED.
• lpThreadId → funkcja CreateThread umieści pod tym adresem numer ID nowo utworzonego wątku.

• Zmienne globalne
• Wiadomości systemu Windows
• Zdarzenia

WM_MOJA_WIADOMOSC EQU WM_USER+100h

.386

.MODEL FLAT, STDCALL

OPTION CASEMAP:NONE

WinMain PROTO :DWORD, :DWORD, :DWORD, :DWORD

INCLUDE    \masm32\include\windows.inc
INCLUDE    \masm32\include\user32.inc
INCLUDE    \masm32\include\kernel32.inc
INCLUDELIB \masm32\lib\user32.lib
INCLUDELIB \masm32\lib\kernel32.lib

.CONST

IDM_CREATE_THREAD EQU 1
IDM_EXIT          EQU 2
WM_FINISH         EQU WM_USER+100h

.DATA

ClassName DB "Win32ASMThreadClass", 0
AppName   DB "Program wielowątkowy w asemblerze", 0
MenuName  DB "FirstMenu", 0

.DATA?

hInstance   HINSTANCE ?
CommandLine LPSTR     ?
hMenu       HANDLE    ?
ExitCode    DWORD     ?
hwnd        HANDLE    ?
ThreadID    DWORD     ?

.CODE

start:
    INVOKE GetModuleHandle, NULL
    mov    hInstance, eax
    INVOKE GetCommandLine
    mov    CommandLine, eax
    INVOKE WinMain, hInstance, NULL, CommandLine, SW_SHOWDEFAULT
    INVOKE ExitProcess, eax

WinMain PROC hInst:     HINSTANCE,\
             hPrevInst: HINSTANCE,\
             CmdLine:   LPSTR,\
             CmdShow:   DWORD

LOCAL wc  : WNDCLASSEX
LOCAL msg : MSG

    mov    wc.cbSize, SIZEOF WNDCLASSEX
    mov    wc.style, CS_HREDRAW OR CS_VREDRAW
    mov    wc.lpfnWndProc, OFFSET WndProc
    mov    wc.cbClsExtra, NULL
    mov    wc.cbWndExtra, NULL
    push   hInst
    pop    wc.hInstance
    mov    wc.hbrBackground, COLOR_WINDOW+1
    mov    wc.lpszMenuName, OFFSET MenuName
    mov    wc.lpszClassName, OFFSET ClassName
    INVOKE LoadIcon, NULL, IDI_APPLICATION
    mov    wc.hIcon, eax
    mov    wc.hIconSm, eax
    INVOKE LoadCursor, NULL, IDC_ARROW
    mov    wc.hCursor, eax
    INVOKE RegisterClassEx, ADDR wc
    INVOKE CreateWindowEx, WS_EX_CLIENTEDGE,\
                           ADDR ClassName, ADDR AppName,\
                           WS_OVERLAPPEDWINDOW, CW_USEDEFAULT,\
                           CW_USEDEFAULT, 300, 200, NULL, NULL,\
                           hInst, NULL
    mov    hwnd, eax
    INVOKE ShowWindow, hwnd, SW_SHOWNORMAL
    INVOKE UpdateWindow, hwnd
    INVOKE GetMenu, hwnd
    mov    hMenu, eax

    .WHILE TRUE
        INVOKE GetMessage, ADDR msg, NULL, 0, 0
        .BREAK .IF (!eax)
        INVOKE TranslateMessage, ADDR msg
        INVOKE DispatchMessage, ADDR msg
    .ENDW

    mov eax, msg.wParam
    ret

WinMain ENDP

WndProc PROC hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM

    .IF uMsg==WM_DESTROY
        INVOKE PostQuitMessage, NULL
    .ELSEIF uMsg==WM_COMMAND
        mov eax, wParam
        .IF lParam==0
            .IF ax==IDM_CREATE_THREAD
                mov    eax, OFFSET ThreadProc
                INVOKE CreateThread, NULL, NULL, eax,\
                                     NULL, NORMAL_PRIORITY_CLASS,\
                                     ADDR ThreadID
                INVOKE CloseHandle, eax
            .ELSE
                INVOKE DestroyWindow, hWnd
            .ENDIF
        .ENDIF
    .ELSEIF uMsg==WM_FINISH
        INVOKE MessageBox, NULL, ADDR AppName, ADDR AppName, MB_OK
    .ELSE
        INVOKE DefWindowProc, hWnd, uMsg, wParam, lParam
        ret
    .ENDIF

    xor eax, eax
    ret

WndProc ENDP

ThreadProc PROC USES ecx Param:DWORD

    mov    ecx, 600000000
Loop1:
    add    eax, eax
    loop   Loop1
    INVOKE SendMessage, hwnd, WM_FINISH, NULL, NULL
    ret

ThreadProc ENDP

END start

// Stałe dla menu

#define IDM_CREATE_THREAD 1
#define IDM_EXIT          2

FirstMenu MENU
{
POPUP "&Proces"
    {
         MENUITEM "&Twórz Wątek", IDM_CREATE_THREAD
         MENUITEM SEPARATOR
         MENUITEM "&Koniec", IDM_EXIT
    }
}

    .IF ax==IDM_CREATE_THREAD
        mov    eax, OFFSET ThreadProc
        INVOKE CreateThread, NULL, NULL, eax,\
                             NULL, NORMAL_PRIORITY_CLASS,\
                             ADDR ThreadID
        INVOKE CloseHandle, eax

ThreadProc PROC USES ecx Param:DWORD

    mov    ecx, 600000000
Loop1:
    add    eax, eax
    loop   Loop1
    INVOKE SendMessage, hwnd, WM_FINISH, NULL, NULL
    ret

ThreadProc ENDP

WM_FINISH EQU WM_USER+100h

• dodaj element menu o treści Zatrzymaj Wątek
• dodaj globalną zmienną używaną w charakterze znacznika polecenia. Wartość TRUE oznacza zatrzymanie wątku, FALSE kontynuację
• zmodyfikuj procedurę ThreadProc, aby w pętli sprawdzała stan znacznika polecenia

{********************************
**  I Liceum Ogólnokształcące  **
**           w Tarnowie        **
**       mgr Jerzy Wałaszek    **
********************************}

program Thread;

uses Windows;

const
  IDM_CREATE_THREAD  = 1;
  IDM_EXIT           = 2;
  WM_FINISH          = WM_USER + $100;
  ClassName          = 'Win32ASMThreadClass';
  AppName            = 'Program wielowątkowy w FreePascalu';
  MenuName           = 'FirstMenu';

var
  hInstance : HINST;
  hMenu     : HANDLE;
  ExitCode  : longword;
  hwnd      : HANDLE;
  ThreadID  : longword;

procedure ThreadProc(Param:DWORD);
var
  i : longword;
begin
  i := 600000000;
  while (i > 0) do i := i - 1;
  SendMessage(hwnd,WM_FINISH,0,0);
end;

function WndProc(hWnd:HANDLE;uMsg:UINT;wParam:WPARAM;lParam:LPARAM) : longint;
begin
  Result := 0;
  case uMsg of
    WM_DESTROY: PostQuitMessage(0);
    WM_COMMAND:
      if lParam = 0 then
      begin
        if (wParam and $ffff) = IDM_CREATE_THREAD then
          CloseHandle(CreateThread(0,0,@ThreadProc,0,NORMAL_PRIORITY_CLASS,ThreadID))
        else DestroyWindow(hWnd);
      end;
    WM_FINISH: MessageBox(0,AppName,AppName,MB_OK);
    else Result := DefWindowProc(hWnd,uMsg,wParam,lParam);
  end;
end;

function WinMain(hInst,hPrevInst:HINST;CmdLine:LPSTR;CmdShow:DWORD) : longint;
var
  wc  : WNDCLASSEX;
  msg : MSG;
begin
  with wc do
  begin
    cbSize        := sizeof(WNDCLASSEX);
    style         := CS_HREDRAW or CS_VREDRAW;
    lpfnWndProc   := @WndProc;
    cbClsExtra    := 0;
    cbWndExtra    := 0;
    hInstance     := hInst;
    hbrBackground := COLOR_WINDOW + 1;
    lpszMenuName  := MenuName;
    lpszClassName := ClassName;
    hIcon         := LoadIcon(0,IDI_APPLICATION);
    hIconSm       := hIcon;
    hCursor       := LoadCursor(0,IDC_ARROW);
  end;
  RegisterClassEx(wc);
  hwnd := CreateWindowEx(WS_EX_CLIENTEDGE,ClassName,AppName,
                         WS_OVERLAPPEDWINDOW, CW_USEDEFAULT,CW_USEDEFAULT,
                         300,200,0,0,hInst,0);
  ShowWindow(hwnd,SW_SHOWNORMAL);
  UpdateWindow(hwnd);
  hMenu := GetMenu(hwnd);
  while GetMessage(msg,0,0,0) do
  begin
    TranslateMessage(msg);
    DispatchMessage(msg);
  end;
  Result := msg.wParam;
end;

begin
  hInstance := GetModuleHandle(0);
  ExitProcess(WinMain(hInstance,0,GetCommandLine,SW_SHOWDEFAULT));
end.